Tự Học IoT Bài 04: Tự Làm Máy Đếm Sản Phẩm Với ESP32 & Cảm Biến Hồng Ngoại (Phần 1)

/*
  ESP32 DEV MODULE (30 PIN) - IR PRODUCT COUNTER + LCD 20x4 I2C + DTG IOT PLATFORM

  Thu vien cai tu Arduino IDE > Library Manager:
    LiquidCrystal I2C - Frank de Brabander
    Wire.h va Arduino.h co san trong ESP32 board package.

  CHAN CUNG MOT BEN, LIEN TIEP NHAU TREN ESP32 DEVKIT V1 30 PIN:
    GPIO18 -> SDA (LCD I2C)
    GPIO19 -> SCL (LCD I2C)
    GPIO21 <- OUT/DO (IR obstacle sensor)

  Cam bien IR: cap nguon 5V.
  LCD 20x4: Cap nguon 5V
  cho SDA/SCL. Noi GND chung tat ca thiet bi.
*/

#include <Arduino.h>
#include <Wire.h>
#include <LiquidCrystal_I2C.h>
#include <dtg.h>

// ====================== CAU HINH ======================
constexpr uint8_t PIN_LCD_SDA = 18;
constexpr uint8_t PIN_LCD_SCL = 19;
constexpr uint8_t PIN_IR      = 21;

constexpr uint8_t LCD_ADDRESS = 0x27; // Neu khong hien thi, thu 0x3F
constexpr uint8_t LCD_COLS    = 20;
constexpr uint8_t LCD_ROWS    = 4;

constexpr uint8_t IR_ACTIVE_LEVEL = LOW; // Da so module IR: LOW = co vat
constexpr uint32_t FILTER_MS      = 15;  // Loc nhieu (ms); chinh theo toc do bang tai

LiquidCrystal_I2C lcd(LCD_ADDRESS, LCD_COLS, LCD_ROWS);

// 1) Wi-Fi credentials
// 1) Wi-Fi credentials
static const char *WIFI_SSID    = "your-wifi-ssid";
static const char *WIFI_PASS    = "your-wifi-password";

// 2) Hub project + gateway credentials
static const char *MQTT_HOST    = "your-mqtt-host";
static const uint16_t MQTT_PORT = 8883; 
static const char *PROJECT_ID   = "your-project-id";
static const char *GW_ALIAS     = "your-gateway-alias";
static const char *MQTT_USER    = "your-mqtt-username";
static const char *MQTT_PASS    = "your-mqtt-password";
static const char *CLIENT_ID    = "your-client-id";

static const bool ENABLE_DEBUG  = true;

uint32_t productCount = 0;
bool rawDetected = false;
bool stableDetected = false;
uint32_t lastRawChangeAt = 0;
const int BUTTON_PIN = 0;

// ================= BIEN TRANG THAI IOT =================
bool isIotConnected = false;
bool lastIotState   = false;

DtgWiFi dtg(PROJECT_ID, GW_ALIAS, MQTT_USER, MQTT_PASS, CLIENT_ID);

DTG_CONNECTED() {
  dtgSerialLogConnected(dtg, CLIENT_ID);
}

// In 1 dong du 20 ky tu, khong su dung lcd.clear() lien tuc (tranh nhap nhay)
void printLCDLine(uint8_t row, const char *text) {
  lcd.setCursor(0, row);
  uint8_t i = 0;
  while (i < LCD_COLS && text[i] != '\0') {
    lcd.write((uint8_t)text[i]);
    ++i;
  }
  while (i < LCD_COLS) {
    lcd.write(' ');
    ++i;
  }
}

void showCount() {
  char line[21];
  snprintf(line, sizeof(line), "SO LUONG: %lu", (unsigned long)productCount);
  printLCDLine(1, line);
}

void showSensor() {
  printLCDLine(2, stableDetected ? "IR: CO SAN PHAM" : "IR: SAN SANG");
}

void updateIotStatus(bool connected) {
  if (connected) {
    printLCDLine(3, "IOT: DA KET NOI");
  } else {
    printLCDLine(3, "IOT: CHUA KET NOI");
  }
}

// Ham goi khi dem them 1 san pham
void onProductCounted() {
  ++productCount;
  if (dtg.connected()) {
    // Gui du lieu len IoT platform
    dtg.publish("sl_sanpham", productCount);
  }
  showCount();
  Serial.printf("DA DEM: %lu san pham\n", (unsigned long)productCount);
}

void scanIR() {
  const uint32_t now = millis();
  const bool detectedNow = (digitalRead(PIN_IR) == IR_ACTIVE_LEVEL);

  if (detectedNow != rawDetected) {
    rawDetected = detectedNow;
    lastRawChangeAt = now;
  }

  // Chi cong nhan thay doi neu trang thai lien tuc on dinh du FILTER_MS
  if (rawDetected != stableDetected && (uint32_t)(now - lastRawChangeAt) >= FILTER_MS) {
    stableDetected = rawDetected;
    showSensor();

    if (stableDetected) {
      onProductCounted(); // Dem tai canh bat dau phat hien san pham
    }
  }
}

void scanSerialReset() {
  while (Serial.available() > 0) {
    const char cmd = (char)Serial.read();
    if (cmd == 'R' || cmd == 'r') {
      productCount = 0;
      showCount();
      Serial.println("DA RESET BO DEM VE 0");
    }
  }
}

// Kiem tra va cap nhat trang thai ket noi IoT len LCD
void checkIotConnection() {
  isIotConnected = dtg.connected();

  // Chi cap nhat lai LCD khi trang thai thay doi de tranh giat lag
  if (isIotConnected != lastIotState) {
    lastIotState = isIotConnected;
    updateIotStatus(isIotConnected);
    Serial.printf("TRANG THAI IOT THAY DOI: %s\n", isIotConnected ? "CONNECTED" : "DISCONNECTED");
  }
}

void setup() {
  Serial.begin(115200);
  pinMode(PIN_IR, INPUT_PULLUP);
  pinMode(BUTTON_PIN, INPUT_PULLUP);

  // Doc trang thai ban dau
  rawDetected = (digitalRead(PIN_IR) == IR_ACTIVE_LEVEL);
  stableDetected = rawDetected;
  lastRawChangeAt = millis();

  // Khoi tao I2C va LCD
  Wire.begin(PIN_LCD_SDA, PIN_LCD_SCL);
  Wire.setClock(100000);

  lcd.init();
  lcd.backlight();
  lcd.clear();

  // Khoi tao hien thi ban dau
  printLCDLine(0, "DEM SAN PHAM - ESP32");
  showCount();
  showSensor();
  updateIotStatus(false); // Khoi dau hien "IOT: CHUA KET NOI"

  Serial.println("ESP32 IR COUNTER READY");
  Serial.println("GPIO18=SDA, GPIO19=SCL, GPIO21=IR OUT");
  Serial.println("Nhap R tren Serial Monitor de reset so dem.");

  // Log va ket noi DTG IoT
  dtg.setLogStream(&Serial);
  dtg.begin(WIFI_SSID, WIFI_PASS);
}

void loop() {
  scanIR();
  scanSerialReset();
  dtg.run();
  checkIotConnection(); // Kiem tra va cap nhat LCD khi co thay doi ket noi
}